nixos-config/configs/pepe/home-assistant.nix

{ pkgs, config, lib, ... }:
let unstablePkgs = import <nixpkgs-unstable> { };
in {

  imports = [
    #./home-assistant/chaospott.nix
    #./home-assistant/mpd.nix
    #./home-assistant/timer.nix
    ./home-assistant/kodi.nix
    ./home-assistant/mqtt.nix
    ./home-assistant/sonoff.nix
    ./home-assistant/weather.nix
    ./home-assistant/workday.nix
    ./home-assistant/zigbee2mqtt.nix
  ];

  services.homeAssistantConfig = {

    # turn on to edit GUI
    # lovelace = {};

    homeassistant = {
      latitude = 51.444847;
      longitude = 6.967006;
      elevation = 116;

      auth_providers = [{
        type = "trusted_networks";
        trusted_networks =
          [ config.module.cluster.services.tinc."private".networkSubnet ];
      }];
    };

    prometheus.namespace = "hass";

    input_boolean.bed_room_buttons.icon = "mdi:toggle-switch";

    automation = let
      # todo : at night only turn trigger essential groups
      roomPresents = { roomGroup, presentsGroup }: [
        {
          alias = "presents -> turn on ${roomGroup} lights";
          trigger = {
            platform = "state";
            entity_id = "group.${presentsGroup}";
            from = "off";
            to = "on";
          };
          action = [
            {
              service = "switch.turn_on";
              entity_id = "group.${roomGroup}";
            }
            {
              service = "light.turn_on";
              entity_id = "group.${roomGroup}";
            }
          ];
        }
        {
          alias = "absents -> turn off ${roomGroup} lights";
          trigger = {
            platform = "state";
            entity_id = "group.${presentsGroup}";
            from = "on";
            to = "off";
          };
          action = [
            {
              service = "switch.turn_off";
              entity_id = "group.${roomGroup}";
            }
            {
              service = "light.turn_off";
              entity_id = "group.${roomGroup}";
            }
          ];
        }
      ];
    in lib.flatten (map roomPresents [
      {
        roomGroup = "kitchen_room_lights";
        presentsGroup = "kitchen_room_present";
      }
      {
        roomGroup = "living_room_lights";
        presentsGroup = "living_room_present";
      }
      {
        roomGroup = "floor_room_lights";
        presentsGroup = "floor_room_present";
      }
      {
        roomGroup = "bath_room_lights";
        presentsGroup = "bath_room_present";
      }
      {
        roomGroup = "bed_room_lights";
        presentsGroup = "bed_room_present";
      }
    ]);

    group = let
      create_room = { name, description }: {
        "${name}" = {
          name = "${description}";
          view = false;
          control = "hidden";
          entities = [ ];
        };
        "${name}_lights" = {
          name = "${description} Beleuchtung";
          view = false;
          entities = [ ];
        };
        "${name}_present" = {
          control = "hidden";
          name = "${description} Anwesend";
          view = false;
          entities = [ ];
        };
        "${name}_essential" = {
          control = "hidden";
          name = "${description} Minimale Beleuchtung";
          view = false;
          entities = [ ];
        };
        "view_${name}" = {
          name = description;
          view = true;
          entities = [
            "group.${name}"
            "group.${name}_lights"
            "group.${name}_present"
            "group.${name}_essential"
            "group.${name}_essential_present"
          ];
        };
      };
      create_rooms = rooms:
        lib.foldr (a: b: a // b) { } (map create_room rooms);
      # rooms
      # -----
    in (create_rooms [
      {
        name = "floor_room";
        description = "Flur";
      }
      {
        name = "bed_room";
        description = "Schlafzimmer";
      }
      {
        name = "living_room";
        description = "Wohnzimmer";
      }
      {
        name = "kitchen_room";
        description = "Küche";
      }
      {
        name = "bath_room";
        description = "Klo";
      }
    ]) // {
      view_rooms = {
        name = "Räume";
        view = true;
        entities = [
          "group.floor_room"
          "group.bed_room"
          "group.living_room"
          "group.kitchen_room"
          "group.bath_room"
        ];
      };

      # overview
      # --------
      all_sensors = {
        name = "Alle Sensoren";
        control = "hidden";
      };
      today = {
        control = "hidden";
        name = "Today";
        view = false;
      };
      view_overview = {
        name = "Übersicht";
        view = true;
        entities = [ "group.today" ];
      };

      # other stuff
      # -----------
      tv = {
        name = "TV";
        view = false;
      };
      all_lights = {
        name = "Alle Lampen";
        view = false;
      };
      unknown = {
        control = "hidden";
        name = "Not Used";
        view = false;
        entities = [ ];
      };

    };

    script.turn_all_off.sequence = [ ];
    script.turn_all_lights_off.sequence = [ ];

  };

  services.home-assistant = {
    enable = true;
    package = unstablePkgs.home-assistant.override {
      python3 = unstablePkgs.python37;
      extraPackages = python: [
        # todo : check which is still needed
        python.netdisco
        python.xmltodict
        python.mpd2

        # for mqtt
        python.hbmqtt
        python.paho-mqtt

        # needed for platform workday
        #(python.buildPythonPackage rec {
        #  pname = "holidays";
        #  version = "0.9.10";
        #  src = python.fetchPypi {
        #    inherit pname version;
        #    sha256 =
        #      "9f06d143eb708e8732230260636938f2f57114e94defd8fa2082408e0d422d6f";
        #  };
        #  doCheck = false;
        #  buildInputs = [ pkgs.dateutils ];
        #  propagatedBuildInputs = [ python."python-dateutil" python."six" ];
        #  meta = with pkgs.stdenv.lib; {
        #    homepage = "https://github.com/dr-prodigy/python-holidays";
        #    license = licenses.mit;
        #    description = "Generate and work with holidays in Python";
        #    maintainers = with maintainers; [ mrVanDalo ];
        #  };
        #})
      ];
    };

  };

  # host nginx setup
  services.nginx = {
    enable = true;
    recommendedProxySettings = true;
    virtualHosts = {
      "iot.pepe.private" = {
        serverAliases = [ "hass.pepe.private" "home.pepe.private" ];
        locations."/" = { proxyPass = "http://pepe.private:8123"; };
      };
    };
  };

}