nixos-config/machines/orbi/service-nix-cache.nix

{
  config,
  lib,
  pkgs,
  ...
}:
{

  # nixpkgs.config.packageOverrides = p: {
  #   nix-serve = p.haskellPackages.nix-serve-ng;
  # };

  # generate private key with:
  # nix-store --generate-binary-cache-key my-secret-key my-public-key
  clan.core.facts.services."nix-serve" = {
    secret."nix-serve.key" = { };
    public."nix-serve.pub" = { };
    generator.path = with pkgs; [
      coreutils
      nix
    ];
    generator.script = ''
      nix-store --generate-binary-cache-key "cache.${config.networking.hostName}.wg0" nix-serve.key nix-serve.pub
      mv nix-serve.key "$secrets"/nix-serve.key
      mv nix-serve.pub "$facts"/nix-serve.pub
    '';
  };

  services.nix-serve = {
    enable = true;
    secretKeyFile = config.clan.core.facts.services.nix-serve.secret."nix-serve.key".path;
    port = 5005;
  };

  verify.closed.public.ports.nix-serve = [ config.services.nix-serve.port ];
  verify.localCommands.nix-serve =
    let
      domain = "cache.${config.networking.hostName}.wg0/nix-cache-info";
      curl = lib.getExe pkgs.curl;
      grep = lib.getExe pkgs.gnugrep;
      grepString = "Priority: 50";
    in
    ''
      if ${curl} -s -o /dev/null -w "%{http_code}" ${domain} | ${grep} -q "200"; then
        if ${curl} -s ${domain} | ${grep} -q "${grepString}"; then
          echo "[ OK ] Die Seite hat Statuscode 200 und enthält den String '${grepString}'."
        else
          echo "[Fail] Der Statuscode ist 200, aber die Seite enthält den String '${grepString}' nicht."
        fi
      else
        echo "[Fail] Die Seite hat keinen Statuscode 200."
      fi
    '';

  services.nginx = {
    enable = true;
    virtualHosts."cache.${config.networking.hostName}.wg0" = {
      locations."/".extraConfig = ''
        proxy_pass http://localhost:${toString config.services.nix-serve.port};
        allow ${config.wireguard.wg0.subnet};
        deny all;
      '';
      # curl https://cache.nixos.org/nix-cache-info
      # lower priority means ask first.
      locations."= /nix-cache-info".extraConfig = ''
        alias ${pkgs.writeText "cache-info" ''
          StoreDir: /nix/store
          WantMassQuery: 1
          Priority: 50
        ''};
        allow ${config.wireguard.wg0.subnet};
        deny all;
      '';
    };
  };
}