nixos-config/configs/pepe/home-assistant/zigbee2mqtt/temperatur.nix

{ pkgs, lib, ... }:
let

  # https://www.zigbee2mqtt.io/devices/WSDCGQ11LM.html
  allDevices = {
    "temperature_sensor_1" = {
      id = "0x00158d0002d79220";
      groups = [ "living_room" ];
    };
    "temperature_sensor_2" = {
      id = "0x00158d0002d7913d";
      groups = [ "living_room" ];
    };
  };

in {

  services.zigbee2mqtt.devices = lib.mapAttrs' (name:
    { id, ... }: {
      name = id;
      value = {
        retain = false;
        friendly_name = name;
      };
    }) allDevices;

  services.homeAssistantConfig = {

    # define meta information sensors
    sensor = lib.flatten (lib.mapAttrsToList (name:
      { ... }: [
        {
          platform = "mqtt";
          name = name;
          state_topic = "zigbee2mqtt/${name}";
          availability_topic = "zigbee2mqtt/bridge/state";
          unit_of_measurement = "°C";
          device_class = "temperature";
          value_template = "{{ value_json.temperature }}";
        }
        {
          platform = "mqtt";
          name = "humidity_${name}";
          state_topic = "zigbee2mqtt/${name}";
          availability_topic = "zigbee2mqtt/bridge/state";
          unit_of_measurement = "%";
          device_class = "humidity";
          value_template = "{{ value_json.humidity }}";
        }
        #{
        #  platform = "mqtt";
        #  name = "pressure_${name}";
        #  state_topic = "zigbee2mqtt/${name}";
        #  availability_topic = "zigbee2mqtt/bridge/state";
        #  unit_of_measurement = "hPa";
        #  device_class = "pressure";
        #  value_template = "{{ value_json.pressure }}";
        #}
        {
          name = "battery_${name}";
          platform = "mqtt";
          state_topic = "zigbee2mqtt/${name}";
          availability_topic = "zigbee2mqtt/bridge/state";
          unit_of_measurement = "%";
          icon = "mdi:battery-10";
          value_template = "{{ value_json.battery }}";
        }
        {
          name = "link_${name}";
          platform = "mqtt";
          state_topic = "zigbee2mqtt/${name}";
          availability_topic = "zigbee2mqtt/bridge/state";
          icon = "mdi:signal";
          unit_of_measurement = "lqi";
          value_template = "{{ value_json.linkquality }}";
        }
      ]) allDevices);

    # create groups
    # -------------
    group = let

      # to have nice panels for every device
      sensorGroups = lib.mapAttrs (name:
        { ... }: {
          control = "hidden";
          entities = [
            "sensor.${name}"
            "sensor.humidity_${name}"
            #"sensor.pressure_${name}"
            "sensor.battery_${name}"
            "sensor.link_${name}"

          ];
        }) allDevices;

      # sort lights into given groups.
      sortedInGroups = let
        groupEntries = lib.zipAttrs (lib.flatten (lib.mapAttrsToList (name:
          { groups ? [ ], ... }:
          map (groupName: { "${groupName}" = "sensor.${name}"; }) groups)
          allDevices));
      in lib.mapAttrs (name: entities: { inherit entities; }) groupEntries;

    in sortedInGroups // sensorGroups // {

      all_sensors.entities =
        lib.mapAttrsToList (name: { ... }: "sensor.${name}") allDevices;
    };
  };

}