nixos-config/homes/palo/packages/nextcloud.nix

{ config, lib, pkgs, ... }:
with pkgs;
with lib;
let
  nextcloud-client = pkgs.legacy_2311.nextcloud-client;

  nextcloudSync = folder:
    let
      password = "$( ${pkgs.pass}/bin/pass show home/nextcloud/palo/nextcloudcmd-token )";
      user = "palo";
    in
    pkgs.writers.writeBashBin "nextcloud-sync-${folder}" ''
      ${nextcloud-client}/bin/nextcloudcmd \
        --path "${folder}" \
        ~/Nextcloud/${folder} \
        "https://${user}:${password}@nextcloud.ingolf-wagner.de"
    '';

  borrow = pkgs.writers.writeDashBin "borrow"
    ''
      ${getExe hledger-ui} \
        --all \
        --theme=terminal \
        --file ~/Nextcloud/Unterlagen/.hledger-borrow "$@"

      ${getExe gum} confirm \
          --affirmative="update" \
          --negative="skip" \
          --default=false \
          "Syncronize with Nextcloud?" && ${getExe(nextcloudSync "Unterlagen")}
    '';
in
{

  config = mkIf (config.gui.enable) {

    home.packages = [

      (nextcloudSync "InstantUpload")
      (nextcloudSync "Pictures")
      (nextcloudSync "Comics")
      (nextcloudSync "Unterlagen")
      (nextcloudSync "Nähen")
      (nextcloudSync "NähenTina")
      (nextcloudSync "Video")
      (nextcloudSync "Kunstbuch")
      (nextcloudSync "AWS-SolutionArchitect-Professional")

      borrow

      nextcloud-client

    ];

    home.shellAliases = {
      schulden = "borrow";
    };

  };

}